" airless.vim: plugin-free statusline + buffer/tab line mimicking the
" darkgeem airline theme. Source it from your vimrc.

set laststatus=2 showtabline=2 noshowmode
set ttimeout ttimeoutlen=50

" Colors (cterm 256). Reapplied on :colorscheme, which clears them.
function! AirlessHi()
	" mode blocks (statusline A/Z, current tab)
	hi ALN cterm=bold ctermfg=15 ctermbg=27
	hi ALI cterm=bold ctermfg=15 ctermbg=70
	hi ALV cterm=bold ctermfg=15 ctermbg=166
	hi ALR cterm=bold ctermfg=15 ctermbg=88
	" middle block, per mode
	hi ALNc ctermfg=27 ctermbg=234
	hi ALIc ctermfg=70 ctermbg=234
	hi ALVc ctermfg=166 ctermbg=234
	hi ALRc ctermfg=144 ctermbg=234
	hi ALMod cterm=bold ctermfg=88 ctermbg=234
	" side blocks (paste, encoding), filetype
	hi ALB ctermfg=144 ctermbg=237
	hi ALFt ctermfg=39 ctermbg=234
	hi StatusLineNC cterm=NONE ctermfg=239 ctermbg=234
	" tabline: other buffers, modified, fill
	hi ALBufMod cterm=bold ctermfg=88 ctermbg=237
	hi ALFill ctermfg=27 ctermbg=234
endfunction
call AirlessHi()

" === Statusline ===
let g:airless_modes = {'n':['NORMAL','N'],'i':['INSERT','I'],'R':['REPLACE','R'],'v':['VISUAL','V'],'V':['V-LINE','V'],"\<C-v>":['V-BLOCK','V'],'c':['COMMAND','N']}

function! AirlessStatus()
	let [l:name, l:k] = get(g:airless_modes, mode()[0], g:airless_modes.n)
	return '%#AL'.l:k.'# '.l:name.' %#ALB#'.(&paste ? ' (paste) ' : ' ')
		\ .'%#'.(&modified ? 'ALMod' : 'AL'.l:k.'c').'# %f%{&ro?" (read-only)":""}'
		\ .'%=%#ALFt#%{&ft} %#ALB# %{&fenc!=""?&fenc:&enc}[%{&ff}] '
		\ .'%#AL'.l:k.'# %p%%  line:%l/%L col:%c '
endfunction
set statusline=%!AirlessStatus()

" === Tabline: buffers, or tabs when more than one ===
" file tail, prefixed with parent dir when tails collide (unique_tail)
function! AirlessName(b, tails)
	let l:t = fnamemodify(bufname(a:b), ':t')
	if l:t == ''
		return '[No Name]'
	endif
	if count(a:tails, l:t) > 1
		let l:t = fnamemodify(bufname(a:b), ':p:h:t').'/'.l:t
	endif
	return substitute(l:t, '%', '%%', 'g')
endfunction

function! AirlessTabs()
	if tabpagenr('$') > 1
		let l:items = map(range(1, tabpagenr('$')), 'tabpagebuflist(v:val)[tabpagewinnr(v:val) - 1]')
		let l:cur = tabpagenr()
		let l:label = ' tabs '
	else
		let l:items = filter(range(1, bufnr('$')), 'buflisted(v:val)')
		let l:cur = index(l:items, bufnr('%')) + 1
		let l:label = ' buffers '
	endif
	let l:tails = map(copy(l:items), 'fnamemodify(bufname(v:val), ":t")')
	let l:s = ''
	let l:i = 0
	for l:b in l:items
		let l:i += 1
		let l:mod = getbufvar(l:b, '&modified')
		let l:grp = l:i == l:cur ? (l:mod ? 'ALI' : 'ALN') : (l:mod ? 'ALBufMod' : 'ALB')
		let l:s .= '%#'.l:grp.'# '.AirlessName(l:b, l:tails).(l:mod ? ' +' : '').' '
	endfor
	return l:s.'%#ALFill#%=%#ALN#'.l:label
endfunction
set tabline=%!AirlessTabs()

augroup airless
	autocmd!
	autocmd ColorScheme * call AirlessHi()
	" noshowmode: vim won't redraw the statusline on insert enter/leave
	autocmd InsertEnter,InsertLeave * call timer_start(0, {-> execute('redrawstatus')})
	autocmd WinLeave * setlocal statusline=%#StatusLineNC#\ %f%=%l/%L
	autocmd WinEnter * setlocal statusline<
augroup end