OHAI! >w</⌗

Hello, hi, good morning/evening/night/void, hi!

What's cooking?

I'm alive.

Why no geemy?⌗

Bad isp, baaaad!⌗

I don't have a proper connection at home, router broke, needs its AC replaced (maybe even the whole power circuit, anyway, ISP is aware and sending another one.

I don't have control over the external router at home, it's kind of a shared connection situation..? Anyway, it's usually fine. Except of course, the ISP is taking their sweet sweet time to send the new router.

And I'm not even sure it'll fix it, but eh.

Router is restarting in a loop, so well, sounds like power issues.

Anyway.

Now I replaced the RJ45 going from external router to internal router (the one I do have control over) by a cable to my 5G router, so it's basically a seamless transition for all my devices (since I'm using an internal router as a NAT, it doesn't even have local IP issues. But I can't host at home anymore. No public IPv4, and v6 are firewalled with no way to open it so meh)

tl;dr: connection bad, can't even stream. I swear I would have if it wasn't for that shitty network situation.

1500ms-3000ms ping at times. I swear I'm gonna go mad. it's been like, three weeks now?

Tried doubling the isp and 5G router?⌗

Yes. No can do. Don't have a load balancer. I rely on a fucking while true loop, on a laptop that's on both my wifi and the isp router (wired) to ping me on discord when it gets an IP for more than an hour without losing it for a single second.

That's an utterly disgusting way to do it, but heh, hot glue based notif daemon works so meh.

Geemy good?⌗

Geemy good.

Geemy happy wolf rn.

Work has its quirks, won't go too in-depth with it but management is bitching about me reading manga on my ereader at my desk. On my fucking lunch break.

If I'm getting thrown out of my mission, I'd rather it be because I royally fucked up, not some bullshit like that.

So, I'll behave and be their good lil' doggy, woof.

Projects? :3c⌗

None really.

Gofer⌗

Been doing some QA testing for gofer, a self-hosted web-based email client, keeping all the conf and your accounts on the server so you don't have to mess with sync and stuff.

@cristianadrielbraun added a howling wolf in the software, they're really really cool, very reactive, and implement shit super quickly (plus they really do listen to users' requests, for a change).

Please give them some love and hit that star if you have a (dead works too) github account.

Pure VIM airline⌗

Ah, yeah, I've also had to write, or more like, cuck coding (the kind where you sit in a chair and watch an AI do shit in your stead) a pure vim replacement to airline's status and tab bars.

Why, you ask? 'cause restricted environment. No plugins, no network, vim 8.0.

Also, no file transfer, so can't transfer the whole airline through a drive.

Had to be short enough to be hand-typed.

Just include that in your vimrc. Only if airline isn't available or it'll fuck up your display. Probably.

" airless.vim: plugin-free statusline + buffer/tab line mimicking the
" darkgeem airline theme. Source it from your vimrc.

set laststatus=2 showtabline=2 noshowmode
set ttimeout ttimeoutlen=50

" Colors (cterm 256). Reapplied on :colorscheme, which clears them.
function! AirlessHi()
	" mode blocks (statusline A/Z, current tab)
	hi ALN cterm=bold ctermfg=15 ctermbg=27
	hi ALI cterm=bold ctermfg=15 ctermbg=70
	hi ALV cterm=bold ctermfg=15 ctermbg=166
	hi ALR cterm=bold ctermfg=15 ctermbg=88
	" middle block, per mode
	hi ALNc ctermfg=27 ctermbg=234
	hi ALIc ctermfg=70 ctermbg=234
	hi ALVc ctermfg=166 ctermbg=234
	hi ALRc ctermfg=144 ctermbg=234
	hi ALMod cterm=bold ctermfg=88 ctermbg=234
	" side blocks (paste, encoding), filetype
	hi ALB ctermfg=144 ctermbg=237
	hi ALFt ctermfg=39 ctermbg=234
	hi StatusLineNC cterm=NONE ctermfg=239 ctermbg=234
	" tabline: other buffers, modified, fill
	hi ALBufMod cterm=bold ctermfg=88 ctermbg=237
	hi ALFill ctermfg=27 ctermbg=234
endfunction
call AirlessHi()

" === Statusline ===
let g:airless_modes = {'n':['NORMAL','N'],'i':['INSERT','I'],'R':['REPLACE','R'],'v':['VISUAL','V'],'V':['V-LINE','V'],"\<C-v>":['V-BLOCK','V'],'c':['COMMAND','N']}

function! AirlessStatus()
	let [l:name, l:k] = get(g:airless_modes, mode()[0], g:airless_modes.n)
	return '%#AL'.l:k.'# '.l:name.' %#ALB#'.(&paste ? ' (paste) ' : ' ')
		\ .'%#'.(&modified ? 'ALMod' : 'AL'.l:k.'c').'# %f%{&ro?" (read-only)":""}'
		\ .'%=%#ALFt#%{&ft} %#ALB# %{&fenc!=""?&fenc:&enc}[%{&ff}] '
		\ .'%#AL'.l:k.'# %p%%  line:%l/%L col:%c '
endfunction
set statusline=%!AirlessStatus()

" === Tabline: buffers, or tabs when more than one ===
" file tail, prefixed with parent dir when tails collide (unique_tail)
function! AirlessName(b, tails)
	let l:t = fnamemodify(bufname(a:b), ':t')
	if l:t == ''
		return '[No Name]'
	endif
	if count(a:tails, l:t) > 1
		let l:t = fnamemodify(bufname(a:b), ':p:h:t').'/'.l:t
	endif
	return substitute(l:t, '%', '%%', 'g')
endfunction

function! AirlessTabs()
	if tabpagenr('$') > 1
		let l:items = map(range(1, tabpagenr('$')), 'tabpagebuflist(v:val)[tabpagewinnr(v:val) - 1]')
		let l:cur = tabpagenr()
		let l:label = ' tabs '
	else
		let l:items = filter(range(1, bufnr('$')), 'buflisted(v:val)')
		let l:cur = index(l:items, bufnr('%')) + 1
		let l:label = ' buffers '
	endif
	let l:tails = map(copy(l:items), 'fnamemodify(bufname(v:val), ":t")')
	let l:s = ''
	let l:i = 0
	for l:b in l:items
		let l:i += 1
		let l:mod = getbufvar(l:b, '&modified')
		let l:grp = l:i == l:cur ? (l:mod ? 'ALI' : 'ALN') : (l:mod ? 'ALBufMod' : 'ALB')
		let l:s .= '%#'.l:grp.'# '.AirlessName(l:b, l:tails).(l:mod ? ' +' : '').' '
	endfor
	return l:s.'%#ALFill#%=%#ALN#'.l:label
endfunction
set tabline=%!AirlessTabs()

augroup airless
	autocmd!
	autocmd ColorScheme * call AirlessHi()
	" noshowmode: vim won't redraw the statusline on insert enter/leave
	autocmd InsertEnter,InsertLeave * call timer_start(0, {-> execute('redrawstatus')})
	autocmd WinLeave * setlocal statusline=%#StatusLineNC#\ %f%=%l/%L
	autocmd WinEnter * setlocal statusline<
augroup end

Other stuff⌗

I updated the status page, made a phrack mirror, and some more.

Yeah, yeah, the status page is now useful and kind of readable now. I was lazy. Fuck you. I did it, now you can look at the status of all my fucking useless services.